;t1ir
;avance-version (07/04/03)
;T1 measurement using inversion recovery
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

;Avance II / III version
;parameters:
;p1      : H 90 at pl1
;pl1     : H pulse power
;d1 : recycle delay
;ns              : 4 (full:4)
;cnst31 : =MAS spin rate (or =1e6 for static)
;l1 : # of rotor cycles (or tau in us)

#include <Avance.incl>
#include <trigg.incl>
                ; definition of external trigger output

"p2=p1*2"
"d11=30m"
"d6=((1s*l1)/cnst31)-(p1/2)-(p2/2)"

;adjust the deadtime to 0 bc of echo
;"acqt0=-p1*2/3.1416"
"acqt0=0"

  trigg
1 ze
2 d1
  1u trigpe4            ;MAS trigger
  p2 ph1
  vd
  1u trigpe4            ;MAS trigger
  p1 ph2
  d6
  (p2 pl1 ph2):f1
  d6
;
  go=2 ph31
  d11 wr #0 if #0 ivd
  lo to 1 times td1
exit

ph1=1 3 
ph2=0 2 1 3 
ph3=1 3 2 0 
ph31=0 2 1 3

;pl1 : f1 channel - power level for pulse (default)
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O                             [30 msec]
;vd : variable delay, taken from vd-list
;NS: 8 * n
;DS: 4
;td1: number of experiments = number of delays in vd-list
;FnMODE: undefined

;define VDLIST

;this pulse program produces a ser-file (PARMOD = 2D)

;$Id: t1ir,v 1.11 2007/04/11 13:34:31 ber Exp $