;satrect1
;
;TS 3 / 08.09.2011
;
;saturation recovery T1 experiment
;pulse program is for 2D acquisition
;establish suitable vd list
;uses mc syntax, so that it can be used in 1D mode for set-up of 
;saturation pulse train
;
;
;Avance III version
;parameters:
;pl1 : X power level
;pl2 : =0W, not used
;pl12 : power level for H 90 and standard proton decoupling 
;pl13 : e.g. used in spinal64_13
;p1 : X 90 degree pulse
;pcpd2 : pulse length in decoupling sequence
;d1 : recycle delay
;d20 : delay in saturation pulse train
;l20 : number of pulses in saturation pulse train, 0 if undesired
;vdlist : list containing tau delays
;FnMODE: QF
;
;
;$CLASS=Solids
;$DIM=pseudo 2D
;$TYPE=direct excitation
;$SUBTYPE=T1/T2
;$COMMENT=saturation recovery T1 experiment

prosol relations=<solids_default>


;"acqt0=-(1u*+p1/2)"
"acqt0=0"

1 ze
2 10m
  d1
3 d20
  (p1 pl1 ph4):f1
  lo to 3 times l20
  vd			;recovery delay
  (p1 pl1 ph1):f1
  1u 
  go=2 ph31
  10m mc #0 to 2 F1QF(ivd)
HaltAcqu, 1m
exit

ph1= 0 0 2 2 1 1 3 3
ph4= 0
ph31= 0 0 2 2 1 1 3 3



;$Id: satrect1nodec,v 1.4.2.2 2017/02/22 17:02:22 ber Exp $