;cpfprfdr (TopSpin 3.0)
;2D exchange NMR in rotating solids  
;rotor synchronized, set cnst31=spin rate, spin rate regulation
;recommended
;see Bennet, Ok, Griffin, Vega J. Chem. Phys. 98, 8624 (1992)
;written by HF, 16.9.98 modified by HF 21.5.07
;see Yoshitaka Ishii J. Chem. Phys. 114, 8473 (2001)
;fpRFDR included JOS 11/11/2004
;tested and upgrade to TS2.1 2007  JOS
;tested and upgraded to TS3.0  05/11/2011  JOS
;modified by dan for H/H correlations

;Proton offset at LG frequency during mix to avoid HH transfer
;use TPPI for transform, phases will be dispersive 

;Avance III version
;parameters:
;d1 : recycle delay
;d0 : =1u t1 evolution period
;in0 : = 1/swh{F1}
;pl12 : power level for H 90  
;pl21 : power level for pi pulse during rfdr
;pcpd2 : pulse length in decoupling sequence
;p1 : H 90 degree pulse
;cnst10  : Frequency reset to Carrier (o1, usually ~100 ppm)
;cnst26 : RFDR offset ppm
;cnst31 : spinning frequency
;l1 : number of rotor cycles for mixing time

;$COMMENT=exchange NMR (RFDR) in rotating solids, rotor synchronized
;$CLASS=Solids
;$DIM=2D
;$TYPE=cross polarisation
;$SUBTYPE=homonuclear correlation
;$OWNER=Bruker
#include<trigg.incl>
#ifdef fprfdr
"p20=1s/(3*cnst31)"
#endif
define delay tau
"tau=0.5s/cnst31-p20/2"
"d31=1s/cnst31"
;"d0=1s/cnst31"

define delay mix
"mix=l1*d31"
;cnst11 : to adjust t=0 for acquisition, if digmod = baseopt
"acqt0=0"
"in0=inf1"
"d0=0.1u"
"cnst10=o1"		; set H dir center to o1p

#include <H_defs.incl>
                        ; defines which channel corresponds to which nucleus

;######################################################
;#           Start of Active Pulse Program            #
;######################################################

1 ze
#include <rot_prot.incl>		
				;protect for too slow rotation

  mix
  d31
2 10m 
  d1 rpp4
 trigg

;######################################################
;#                Initial excitation                  #
;######################################################

  (p1 pl12 ph1):H

;######################################################
;#                   t1 evolution                     #
;#             Polarization is on 1H                 #
;######################################################

  d0

;######################################################
;#             store 1H along Z                      #
;#          turn off 1H briefly for states            #
;######################################################

  (p1 pl12 ph3):H
;
  2m			;need delay to let IySin term vanish for states 
5 tau 			;mixing time with Gullion sequence
  (p20 pl20 ph4^):H
  tau
  lo to 5 times l1
;
  2m 

;######################################################
;#             recall the  1H along Z                #
;#              use echo for baseline                #
;###################################################### 

  (p1 pl12 ph5):H
  tau
  (p2 ph6):H
  tau

;#######################################################
;#                     Acquisition                     #
;#######################################################

  go=2 ph31 
  10m mc #0 to 2 F1PH(ip1,id0)
HaltAcqu, 1m
6 exit

;#####################################
;#             Phase Cycle           #
;#####################################


ph1=0 2 
ph4=0 1 0 1 1 0 1 0	2 3 2 3 3 2 3 2 ;xy16		
ph3=0 0 0 0 0 0 0 0
    2 2 2 2 2 2 2 2
ph5=0 0 2 2 1 1 3 3
ph6=1 1 3 3 2 2 0 0
ph31=0 2 2 0 1 3 3 1 
     2 0 0 2 3 1 1 3

;#####################################
;#          END SEQUENCE             #
;#####################################