;;version: 1.0/ TS3.2 /2013/07/12

; static 1D 1H echo
; need to define both p1 and p2 explicitly
; used for background removal expts

;Avance II / III version
;parameters:
;p1      : H 90 at pl1
;p2      : H 180 at pl1
;pl1     : H pulse power
;d1 : recycle delay
;ns		 : 4 (full:4)


;$COMMENT= single pulse excitation, acquisition without decoupling
;$CLASS=BioSolids
;$DIM=1D
;$TYPE=direct excitation
;$SUBTYPE=Setup

;"acqt0=-p1*2/3.1416"
"acqt0=0"

                            ;##########################
;$EXTERN                    ;# Python insertion point #

Prepare, ze

;######################################################
;#           Start of Active Pulse Program            #
;######################################################

Start, 30m
  d1

  (p1 pl1 ph1):f1
  20u
  (p2 pl1 ph2):f1
  20u

;#######################################################
;#                     Acquisition                     #
;#######################################################

  go=Start ph31         
  30m mc #0 to Start F0(zd)
  
HaltAcqu, 1m
Exit, exit

;#####################################
;#             Phase Cycle           #
;#####################################

ph1= 0 1 2 3 0 1 2 3	; H hard pulse
ph2= 1 2 3 0 3 0 1 2	; H hard pulse

ph31=0 1 2 3		; receiver

;#######################################################