;cpnqs
;
;TS3 / 02.08.2011
;
;checked by SEWE 02.08.2011
;
;
;basic cp experiment with rotor synchronised NQS, refocussed
;
;
;Avance III version
;parameters: 
;pl1 : power level for f1 channel during contact (X)
;pl2 : =0W, not used
;pl11 : power level for X pulses (180)
;pl12 : power level for H 90 and standard proton decoupling 
;pl13 : power level used e.g. in spinal64_13
;sp0 : proton power level during contact
;p2 : X 180 refocussing pulse
;p3 : H 90 degree pulse
;p15 : contact time
;d1 : recycle delay
;d3 : half of NQS dephasing delay normally 20u<d3<100u(must be smaller than d6)
;spnam0 : file name for variable amplitude CP
;cpdprg2 : sequence used for decoupling (tppm15, cw, etc.)
;cnst31 : MAS spinning frequency
;l0 : number of rotor periods for echotime (must be positive)
;pcpd2 : pulse length in decoupling sequence
;zgoptns : -Dlacq, -Dlcp15, or blank to disable protection
;
;$CLASS=Solids
;$DIM=1D
;$TYPE=cross polarisation
;$SUBTYPE=simple 1D
;$COMMENT=basic cp experiment, rotor synchronised NQS

prosol relations=<solids_cp>


"d6=((l0*1s)/cnst31)-p2-de"
define delay del3
"del3=d6-d3"
"acqt0=0"

1 ze			;accumulate into an empty memory

2 d1 do:f2		;recycle delay, decoupler off in go-loop
#ifndef lcp15
#include <p15_prot.incl>
			;make sure p15 does not exceed 10 msec 
			;let supervisor change this pulseprogram if 
			;more is needed
#endif

#ifndef lacq		
			;disable protection file for long acquisition change decoupling power !!! or you risk probe damage
			;if you set the label lacq (ZGOPTNS -Dlacq), the protection is disabled

#include <aq_prot.incl>	
			;allows max. 50 msec acquisition time, supervisor
			;may change  to max. 1s at less than 5 % duty cycle
			;and reduced decoupling field
#endif
  1u fq=cnst21:f2
  (p3 pl12 ph1):f2
  (p15 pl1 ph2):f1 (p15:sp0 ph10):f2
  del3 cpds2:f2		
  d3 do:f2
  (p2 pl11 ph2):f1
  d3
  del3 cpds2:f2		
  go=2 ph31
  1m do:f2
  wr #0
HaltAcqu, 1m
exit

ph0= 0
ph1= 1 3
ph2= 0 0 2 2 1 1 3 3
ph3= 1 1 3 3 2 2 0 0
ph10= 0
ph31= 0 2 2 0 1 3 3 1



;$Id: cpnqs,v 1.7.2.1 2017/02/22 17:02:01 ber Exp $