;cp90
;
;TS3 / 03.06.2011
;
;basic cp experiment with flipback 90 at pl11
;written by HF 1.3.2001
;
;checked by SEWE 02.08.2011
;
;
;Avance III version
;parameters: 
;pl1 : f1 power level for CP
;pl2 : =0W, not used
;pl11 : to determine X 90 or 180 degree pulse
;pl12 : f2 power level for 90 deg + decoupling 
;pl13 : f2 power level in case of special decoupling (e.g. spinal64_13)
;sp0 : proton power level during contact
;p1 : f1 90 or 180 deg pulse at plw11
;p3 : proton 90 at power level plw12
;p15 : contact time at plw1 (f1) and spw0 (f2)
;cpdprg2 : cw, spinal64 (at plw12)
;d1 : recycle delay
;pcpd2 : pulse length in decoupling sequence (e.g. 180-0.2us)
;spnam0 : use e.g. ramp.100 for variable amplitude CP
;zgoptns : -Dfslg, -Dlacq, -Dlcp15, or blank
;
;
;$CLASS=Solids
;$DIM=1D
;$TYPE=cross polarisation
;$SUBTYPE=simple 1D
;$COMMENT=basic cp experiment, flipback pulse on X for 90-degree pulse calibration

prosol relations=<solids_cp>

#include <Avancesolids.incl>
"acqt0=0" ; value for baseopt calculation

1 ze
2 d1 do:f2 
#ifndef lcp15
#include <p15_prot.incl>
			;make sure p15 does not exceed 10 msec 
			;let supervisor change this pulseprogram if 
			;more is needed
#endif

#ifndef lacq		
			;disable protection file for long acquisition change decoupling power !!! or you risk probe damage
			;if you set the label lacq (ZGOPTNS -Dlacq), the protection is disabled

#include <aq_prot.incl>	
			;allows max. 50 msec acquisition time, supervisor
			;may change  to max. 1s at less than 5 % duty cycle
			;and reduced decoupling field
#endif

  1u fq=cnst21:f2
  (p3 pl12 ph1):f2
  (p15 pl1 ph2):f1 (p15:sp0 ph10):f2
  (p1 ph3):f1 (1u pl11):f1 (1u cpds2):f2
  go=2 ph31
  1m do:f2
  wr #0
HaltAcqu, 1m
exit

ph0= 0
ph1= 1 3
ph2= 0 0 2 2 1 1 3 3
ph3= 1 1 3 3 2 2 0 0
ph10= 0
ph31= 0 2 2 0 1 3 3 1



;$Id: cp90,v 1.7 2012/10/09 09:17:28 ber Exp $