;hNCa.dcp
;
;version: 1.0/ TS3.2 /2013/06/17
;
;written for BioToolkit: JOS WTF 10.5.2013
;double-checked: VEDA SEWE July 2013
;
;2D double cp experiment 
;for NCa correlation
;HN CP, then NCa CP
;
;$CLASS=BioSolids
;$DIM=2D
;$TYPE=Heteronuclear
;$SUBTYPE=hNC and DCP
;$COMMENT=hNCa Double CP or PAIN CP


;Avance II / AVIII version
;Parameters:
;p1      : C 90 at pl1
;p2      : C 180 at pl1
;p3      : H 90 at pl2
;p16     : NCa CP at pl5 (f3,N), sp50 (f1,C), pl33 (f2,H)
;p25     : HN CP at sp43 (f3,N) and sp42 (f2,H)
;pl1     : C pulse power
;pl2     : H pulse power
;pl5     : N NCa CP power
;pl12    : H dec power
;pl33    : H dec power during NCa CP
;sp42    : H HN CP power
;sp43    : N HN CP power
;sp50    : C NCa CP power
;d0      : incremented delay (t1)
;d1      : recycle delay; 1 to 5 times T1
;d30     : extra time for constant duty cycle 
;pcpd2   : H dec pulse cpdprg2
;cpdprg2 : Decoupling file cw, tppm (at pl12)
;spnam42 : H ramp use e.g. ramp.10070 for variable amplitude CP
;spnam43 : N ramp use e.g. square.100 for square pulse CP
;spnam50 : CA ramp use e.g. tcn for amplitude modulated tangential pulse CP
;cnst10  : Frequency reset to Carrier (o1, usually ~100 ppm)
;cnst22  : Frequency offset for CA (~55 ppm)
;cnst30  : expected td1 for use in constant duty cycle (-DCDC)
;cnst31  : MAS rotation rate in Hz
;inf1:  1/SW(N) = 2 * DW(N)
;in0 : = inf1
;in30: = inf1
;l0 : loopcounter for F1
;ZGOPTNS : -DCDC : for constant duty cycle
;		   or blank
;FnMODE: TPPI, States or States-TPPI
;ns: MIN. 4 (full:8)
;
;#######################################################
;#                                                     #
;# N-C SPECIFIC CP                                     #
;# Baldus, M.; Petkova, A. T.; Herzfeld, J. H.;        #
;#    Griffin, R. G. Mol. Phys. 1998,95, 1197-1207.    #
;# M. Hong and R.G. Griffin;                           #
;#    J. Am. Chem. Soc. 120, 7113-7114                 #
;#                                                     #
;#  pl5 (15N) = 5*wr/2                                 #
;#  sp50 (13C) = 3*wr/2		                       #
;#                                                     #
;# N-C PAIN CP (use square pulse shape)                #
;#  J. Lewandowski, G. De Pape, and                    #
;#     R. G. Griffin; J Am Chem Soc. 129(4): 728-29    #
;#                                                     #
;#  pl5 (15N) = 5*wr/2                                 #
;#  sp50 (13C) = 5*wr/2  and various other conditions  #
;#                                                     #
;#######################################################


prosol relations=<biosolCHN>


#include <CHN_defs.incl>
			; defines which channel corresponds to which nucleus

#include <trigg.incl>
			; definition of external trigger output


"acqt0=-1u"

"in0=inf1"                  ;##########################
"d0=1u"                     ;#    t1_init => 0, 0     #
"in30=inf1"                 ;##########################
"l0=0"
"cnst10=o1"

define delay ONTIME         ;##########################
define loopcounter T1evo    ;#   Constant Duty Cycle  #
                            ;##########################
#ifdef CDC
"T1evo=larger(td1,cnst30)"
"d30=T1evo*(in30+2u)"
#endif                      /* CDC */


                            ;##########################
;$EXTERN                    ;# python insertion point #
                            ;##########################

Prepare, ze

"d30=d30/2"

"ONTIME=aq+d0+d30+p25+p16"

;######################################################
;#               Protections: Pre-Check               #
;######################################################

#include <acq_prot.incl>	
			;Max. 50 ms acquisition time
#include <p16bio_prot.incl>
			;p16 max. 10 ms
#include <p25bio_prot.incl>
			;p25 max. 10 ms
#include <t1_prot.incl>
			;check t1 evolution time
#include <ONTIME_prot.incl>
			;total RF deposition restriction

;######################################################
;#           Start of Active Pulse Program            #
;######################################################

Start, 30m do:H
  d1

  trigg

  1u fq=0.0:H				;set 1H on resonance

if "l0>0"
{
  "d51=d0-2u"
}

;######################################################
;#                Initial excitation                  #
;######################################################

  (p3  pl2 ph1):H
  (p25:sp43 ph2):N  (p25:sp42 ph0):H

;######################################################
;#                   t1 evolution                     #
;######################################################

  (0.5u pl12):H

if "l0>0"
{
  0.5u cpds2:H
   (center 
	(d51)   
	(p1 pl1 ph20 p2 ph21 p1 ph20):C	
    )
  0.5u do:H
}

;######################################################
;#           Second CP Period (SPECIFIC/PAIN)         #
;######################################################

  0.5u fq=cnst22(bf ppm):C

 (p16:sp50 ph4):C (p16 pl33 ph1):H (p16 pl5 ph3):N

 (0.5u fq=cnst10(bf hz)):C (0.5u  pl12):H
  0.5u cpds2:H 
  
;#######################################################
;#                     Acquisition                     #
;#######################################################

gosc ph31 		;start ADC with ph31 signal routing

#ifdef CDC
  d30                   
#endif					/*end of CDC*/

1m do:H 				
lo to Start times ns

30m mc #0 to Start 
F1PH(calph(ph2, +90), caldel(d0, +in0) & caldel(d30, -in30) & calclc(l0, 1))



HaltAcqu, 1m
exit

;#####################################
;#             Phase Cycle           #
;#####################################

ph0= 0				; H HN CP Spin lock
ph1= 1 3 			; H hard pulse and during NC CP
ph2= 0 				; N HN CP Spin lock
ph3= 0 0 2 2			; N NCa CP Spin lock
ph4= 0 0 1 1 2 2 3 3		; C NCa CP Spin lock

ph31= 3 1 2 0 1 3 0 2 		; receiver

ph20= 0				; C 90 hard pulse
ph21= 1				; C 180 pulse

;#######################################################



;$Id: hNCa.dcp,v 1.1.2.4 2017/02/23 17:10:58 ber Exp $