;cpfprfdr (TopSpin 3.0)
;2D exchange NMR in rotating solids  
;rotor synchronized, set cnst31=spin rate, spin rate regulation
;recommended
;see Bennet, Ok, Griffin, Vega J. Chem. Phys. 98, 8624 (1992)
;written by HF, 16.9.98 modified by HF 21.5.07
;see Yoshitaka Ishii J. Chem. Phys. 114, 8473 (2001)
;fpRFDR included JOS 11/11/2004
;tested and upgrade to TS2.1 2007  JOS
;tested and upgraded to TS3.0  05/11/2011  JOS
;modified by dan

;Proton offset at LG frequency during mix to avoid HH transfer
;use TPPI for transform, phases will be dispersive 

;Avance III version
;parameters:
;d1 : recycle delay
;d0 : =1u t1 evolution period
;in0 : = 1/swh{F1}
;pl1 : X power level
;pl11 : power level for X pulses
;sp0 : carbon power level during contact
;pl2 : proton power level during contact 
;pl12 : power level for H 90  
;pl22 : standard proton decoupling 
;pl13 : power level of LG decoupling, 120 dB at high spin rates >15 kHz
;pl21 : power level for pi pulse during rfdr
;pcpd2 : pulse length in decoupling sequence
;p15 : contact time at pl1 (f1) and pl2 (f2)
;p10 : pulse length for FSLG shape
;p3 : H 90 degree pulse
;p1 : X 90 degree pulse
;p2 : X 180 degree pulse
;cpdprg2 : Sequence used for decoupling in t1 t2 (tppm15, cw, etc.)
;cpdprg1 : cwlg, using pl13
;cpdprg3 : Sequence for decoupling in mixing
;spnam0 : file name for variable amplitude CP
;cnst10  : Frequency reset to Carrier (o1, usually ~100 ppm)
;cnst20 : proton RF field to calculate LG parameters
;cnst21 : =0, proton offset
;cnst22 : +ve Lee-Goldburg offset
;cnst24 : additional Lee-Goldburg offset
;cnst26 : RFDR offset ppm
;cnst31 : spinning frequency
;l1 : number of rotor cycles for mixing time

;$COMMENT=exchange NMR (RFDR) in rotating solids, rotor synchronized
;$CLASS=Solids
;$DIM=2D
;$TYPE=cross polarisation
;$SUBTYPE=homonuclear correlation
;$OWNER=Bruker
#include<trigg.incl>
#ifdef fprfdr
"p2=1s/(3*cnst31)"
#endif
define delay tau
"tau=0.5s/cnst31-p2/2"
"d31=1s/cnst31"
;"d0=1s/cnst31"

define delay mix
"mix=l1*d31"
;cnst11 : to adjust t=0 for acquisition, if digmod = baseopt
"acqt0=1u*cnst11"
"in0=inf1"
"d0=0.1u"
"cnst10=o1"		; set C dir center to o1p

#include <CHN_defs.incl>
                        ; defines which channel corresponds to which nucleus
#include <lgcalc.incl>
	;calculates the lg offset cnst22 from cnst20=RF field

;######################################################
;#           Start of Active Pulse Program            #
;######################################################

1 ze
#include <rot_prot.incl>		
				;protect for too slow rotation
#include <p15_prot.incl>	
			;make sure p15 does not exceed 10 msec	
			;let supervisor change this pulseprogram if 
			;more is needed
#include <aq_prot.incl>	
			;allows max. 50 msec acquisition time, supervisor
			;may change  to max. 1s at less than 5 % duty cycle
			;and reduced decoupling field
  mix
  d31
2 10m do:H
  d1 rpp4
  2u fq=cnst21:H
 trigg

;######################################################
;#                Initial excitation                  #
;######################################################

  (p3 pl12 ph1):H
  (p15 pl1 ph2):C (p15:sp0 ph10):H

;######################################################
;#                   t1 evolution                     #
;#             Polarization is on 13C                 #
;######################################################

  d0 cpds2:H

;######################################################
;#             store 13C along Z                      #
;#          turn off 1H briefly for states            #
;######################################################

  (p1 pl11 ph3 fq=cnst10(bf hz)):C  	;something like IzCos + IySin nox	
  0.1u do:H		;turn off decoupler 
  0.5u fq=cnst26(bf ppm):C              ;offset for RFDR
;
  2m			;need delay to let IySin term vanish for states 
;  1u cpds3:H		; NO DECOUPLING HIGH VR
5 tau 			;mixing time with Gullion sequence
  (p2 pl21 ph4^):C
  tau
  lo to 5 times l1
;  0.1u do:H
;
  2m 
  0.5u fq=cnst10(bf hz):C               ;C back to o1p

;######################################################
;#             recall the  13C along Z                #
;###################################################### 

 (p1 pl11 ph5):C 

;#######################################################
;#                     Acquisition                     #
;#######################################################

  go=2 ph31 cpds2:H
  1m do:H
  10m mc #0 to 2 F1PH(ip2,id0)
HaltAcqu, 1m
6 exit

;#####################################
;#             Phase Cycle           #
;#####################################


ph1=3 1
ph2=3
ph3= 0 0 0 0 2 2 2 2
ph4=0 1 0 1 1 0 1 0	2 3 2 3 3 2 3 2 ;xy16		
ph5=0 0 0 0 0 0 0 0
    2 2 2 2 2 2 2 2
ph10=0 0 2 2
ph31=0 2 2 0 2 0 0 2 
     2 0 0 2 0 2 2 0