;cosydfesgpphpp
;avance-version (12/01/11)
;2D homonuclear shift correlation
;with double quantum filter
;phase sensitive
;water suppression using excitation sculpting with gradients
;allowing for presaturation during relaxation delay in cases 
;   of radiation damping
;using purge pulses before d1
;be sure in10=in0; and in27 is right.
;
;phasecycle: A. Derome & M. Williamson, J. Magn. Reson. 88,
;               177 - 185 (1990)
;T.-L. Hwang & A.J. Shaka, J. Magn. Reson.,
;   Series A 112 275-279 (1995)
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

;#################################
;# Include files and prosol	#
;#################################

prosol relations=<triple>

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

;#################################
;# Define Delays/increments	#
;#################################

"p2=p1*2"
"p15=300u"
"p17=2.5m"

"d11=30m"
"d12=20u"
"d13=5u"
"d16=125u"

"in0=inf1/2"
"in27=100us*16/ns"
"d0=d25-(ns*0.5-0.5)*in27-p15-150u"
"d10=d25-(ns*0.5-0.5)*in27-p15-150u"

;"d0=d25-in27-p15-150u"
;"d10=d25-in27-p15-150u"

"DELTA1=d26-p15"
"in10=in0"

"d27=5u"

;#################################

"acqt0=0"
baseopt_echo

;#################################
;# Start Pulse Sequence    	#
;#################################

1 ze
2 d11
3 d12; pl9:f1
  3m
4 d1 ;cw:f1 ph29
  d13; do:f1
  d12 pl1:f1
  50u UNBLKGRAD

;#################################
;#   Excitation 1st pulse  	#
;#################################

  p1 ph3
  4u
  p15:gp1
  150u

;#################################
;#   ct t1 Evolution          	#
;#################################

  d0
  d27

;#################################
;#   180                   	#
;#################################

  p2 ph4

;#################################
;#   ct t1 Evolution          	#
;#################################

  4u
  p15:gp1
  150u
  d10
  d27

;#################################
;#   Store on Z            	#
;#################################

  p1 ph5
  4u
  p15:gp2
  DELTA1

;#################################
;#   180                   	#
;#################################

  p2 ph1
  4u
  p15:gp2
  DELTA1 id27

;#################################
;#   Trim Pulse            	#
;#################################

  p17 ph6
  4u
  p16:gp3
  d16 pl0:f1
  (p12:sp1 ph8:r):f1
  4u
  d12 pl1:f1

;#################################
;#   180                   	#
;#################################

  p2 ph9
  4u
  p16:gp3
  d16
  8u
  p16:gp4
  d16 pl0:f1
  (p12:sp1 ph10:r):f1
  4u
  d12 pl1:f1

;#################################
;#   180                   	#
;#################################

  p2 ph11
  4u
  p16:gp4
  d16
  4u BLKGRAD

;#################################
;# Receiver on store data  	#
;#################################

  go=2 ph31
  4u rd27
  d11 mc #0 to 2 F1PH(calph(ph3, +90) & calph(ph29, +90), caldel(d0, +in0) & caldel(d10, -in10) & calph(ph4, +180) )

; d11 mc #0 to 2 F1PH(ip3 & ip29, id0 & dd10 & ip4*2)  ; old statement

exit

;#################################
;# Phase Cycling            	#
;#################################

ph1=0
ph2=1
ph3=0 2 1 3
ph4=0
ph5=1 1 0 0
ph6=1 1 0 0 3 3 2 2
ph8=0
ph9=2
ph10=0
ph11=2
ph29=0
ph31=0 2 1 3

;#################################
;# Ased statements         	#
;#################################

;in0: 1/(1 * SW) = 2 * DW
;in10 = in0: 1/(1 * SW) = 2 * DW
;in27: [50 - 500 us]= 100us*16/ns
;pl1 : f1 channel - power level for pulse (default)
;pl9 : f1 channel - power level for presaturation
;      set to 75-80 to reduce water radiation damping
;p0 : f1 channel -  90 degree pulse at pl1
;                      use for fine adjustment
;p1 : f1 channel -  90 degree high power pulse
;p15: gradient pulse
;p16: homospoil/gradient pulse
;p17: trim pulse                                     [2.5 ms]
;d0 : incremented delay (2D)                         [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d10: incremented delay (2D)                         [3 usec]
;d11: delay for disk I/O                             [30 msec]
;d12: delay for power switching                      [20 usec]
;d13: short delay                                    [4 usec]
;d16: delay for homospoil/gradient recovery
;d19: delay for binomial water suppression
;     d19 = (1/(2*d)), d = distance of next null (in Hz)
;d25: constant time [11-15 msec]
;d26: mixing time [11-15 msec]
;d27: used for filter of artifacts
;in0: 1/(1 * SW) = 2 * DW
;in27: [50 - 500 us]
;nd0: 2
;NS : 8*n
;DS : 8
;td1: number of experiments
;FnMODE: States-TPPI, TPPI, States or QSEC

;#################################
;# Gradient Statements     	#
;#################################

;for z-only gradients:
;gpz1: 10%
;gpz2: 20%
;gpz3: 30%
;gpz4: 55%

;use gradient files:
;gpnam1: SINE.50
;gpnam2: SINE.50
;gpnam3: SINE.100
;gpnam4: SINE.100

;#################################
;# Processing Statements         #
;#################################

;PHC0(F1): 90
;PHC1(F1): -180
;FCOR(F1): 1

;$Id: cosydfesgpphpp,v 1.7 2012/01/31 17:49:22 ber Exp $

;#################################
;#################################
;#################################